Move all awk functions to separate files

awk/blockquote.awk

@@ -0,0 +1,14 @@
+BEGIN { in_bq = 0 }
+/^>[[:space:]]?/ {
+    if (!in_bq) { print "<blockquote>"; in_bq = 1 }
+    sub(/^>[[:space:]]?/, "", $0)
+    print $0
+    next
+}
+{
+    if (in_bq) { print "</blockquote>"; in_bq = 0 }
+    print
+}
+END {
+    if (in_bq) print "</blockquote>"
+}

awk/blockquote_to_admonition.awk

@@ -0,0 +1,46 @@
+function cap(s) { return toupper(substr(s, 1, 1)) tolower(substr(s, 2)) }
+BEGIN { count = 0 }
+{ lines[++count] = $0 }
+END {
+    i = 1
+    while (i <= count) {
+        if (lines[i] == "<blockquote>") {
+            j = i + 1
+            while (j <= count && lines[j] != "</blockquote>") j++
+            if (j <= count) {
+                first = ""
+                first_idx = 0
+                for (k = i + 1; k < j; k++) {
+                    if (lines[k] != "") {
+                        first = lines[k]
+                        first_idx = k
+                        break
+                    }
+                }
+                if (first ~ /^\[![A-Za-z]+\]$/) {
+                    kind = first
+                    sub(/^\[!/, "", kind)
+                    sub(/\]$/, "", kind)
+                    lkind = tolower(kind)
+                    if (lkind == "note" || lkind == "tip" || lkind == "important" || lkind == "warning" || lkind == "caution") {
+                        print "<div class=\"admonition admonition-" lkind "\">"
+                        print "<p class=\"admonition-title\">" cap(lkind) "</p>"
+                        has_body = 0
+                        for (k = first_idx + 1; k < j; k++) {
+                            if (lines[k] != "") {
+                                print "<p>" lines[k] "</p>"
+                                has_body = 1
+                            }
+                        }
+                        if (!has_body) print "<p></p>"
+                        print "</div>"
+                        i = j + 1
+                        continue
+                    }
+                }
+            }
+        }
+        print lines[i]
+        i++
+    }
+}

awk/breaks.awk

@@ -0,0 +1,5 @@
+{
+    if ($0 == "" && prev == "") print "<br />"
+    else print $0
+    prev = $0
+}

awk/fenced_code.awk

@@ -0,0 +1,27 @@
+BEGIN { in_fence = 0; first_line = 0 }
+{
+    if (!in_fence && $0 ~ /^```/) {
+        in_fence = 1
+        first_line = 1
+        next
+    }
+    if (in_fence && $0 ~ /^```[[:space:]]*$/) {
+        print "</code></pre>"
+        in_fence = 0
+        next
+    }
+    if (in_fence) {
+        if (first_line) {
+            first_line = 0
+            if ($0 == "") next
+            print "<pre><code>" $0
+        } else {
+            print
+        }
+    } else {
+        print
+    }
+}
+END {
+    if (in_fence) print "</code></pre>"
+}

awk/generate_sidebar.awk

@@ -4,6 +4,34 @@ function title_from_name(name) {
     return name
 }
 
+function compare_paths(p1, p2,    parts1, parts2, n1, n2, i, name1, name2, lname1, lname2, w1, w2) {
+    n1 = split(p1, parts1, "/")
+    n2 = split(p2, parts2, "/")
+    for (i = 1; i <= n1 && i <= n2; i++) {
+        name1 = parts1[i]
+        name2 = parts2[i]
+        if (i == n1) gsub(/\.md$/, "", name1)
+        if (i == n2) gsub(/\.md$/, "", name2)
+        lname1 = tolower(name1)
+        lname2 = tolower(name2)
+
+        if (lname1 == "index" && i == n1 && lname2 != "index") return -1
+        if (lname2 == "index" && i == n2 && lname1 != "index") return 1
+
+        w1 = (lname1 in custom_order ? custom_order[lname1] : 999999)
+        w2 = (lname2 in custom_order ? custom_order[lname2] : 999999)
+
+        if (w1 < w2) return -1
+        if (w1 > w2) return 1
+
+        if (lname1 < lname2) return -1
+        if (lname1 > lname2) return 1
+    }
+    if (n1 < n2) return -1
+    if (n1 > n2) return 1
+    return 0
+}
+
 BEGIN {
     n_dlines = split(dinfo, dlines, "\n")
     for (i = 1; i <= n_dlines; i++) {
@@ -39,33 +67,6 @@ BEGIN {
         has_index[dir] = 1
     }
 }
-function compare_paths(p1, p2,    parts1, parts2, n1, n2, i, name1, name2, lname1, lname2, w1, w2) {
-    n1 = split(p1, parts1, "/")
-    n2 = split(p2, parts2, "/")
-    for (i = 1; i <= n1 && i <= n2; i++) {
-        name1 = parts1[i]
-        name2 = parts2[i]
-        if (i == n1) gsub(/\.md$/, "", name1)
-        if (i == n2) gsub(/\.md$/, "", name2)
-        lname1 = tolower(name1)
-        lname2 = tolower(name2)
-
-        if (lname1 == "index" && i == n1 && lname2 != "index") return -1
-        if (lname2 == "index" && i == n2 && lname1 != "index") return 1
-
-        w1 = (lname1 in custom_order ? custom_order[lname1] : 999999)
-        w2 = (lname2 in custom_order ? custom_order[lname2] : 999999)
-
-        if (w1 < w2) return -1
-        if (w1 > w2) return 1
-
-        if (lname1 < lname2) return -1
-        if (lname1 > lname2) return 1
-    }
-    if (n1 < n2) return -1
-    if (n1 > n2) return 1
-    return 0
-}
 
 END {
     for (i = 0; i < count - 1; i++) {
@@ -78,7 +79,6 @@ END {
         }
     }
 
-
     print "<ul>"
     if ("index.md" in all_paths) {
         print "<li><a href=\"/index.html\">Home</a></li>"

awk/headers.awk

@@ -0,0 +1,65 @@
+function strip_markdown(s) {
+    gsub(/<[^>]+>/, "", s)
+    gsub(/[*_`~]/, "", s)
+    gsub(/[\[\]]/, "", s)
+    gsub(/\([^\)]*\)/, "", s)
+    sub(/^[[:space:]]*/, "", s)
+    sub(/[[:space:]]*$/, "", s)
+    return s
+}
+BEGIN {
+    has_prev = 0
+    in_pre = 0
+}
+{
+    if ($0 ~ /^<pre><code>/) {
+        in_pre = 1
+        if (has_prev && prev != "") { print prev; has_prev = 0 }
+        print
+        next
+    }
+    if (in_pre) {
+        if ($0 ~ /<\/code><\/pre>/) in_pre = 0
+        print
+        next
+    }
+
+    if ($0 ~ /^=+$/ && has_prev && prev != "" && prev !~ /^<[a-z]/) {
+        print "<h1 id=\"" strip_markdown(prev) "\">" prev "</h1>"
+        has_prev = 0
+    } else if ($0 ~ /^-+$/ && has_prev && prev != "" && prev !~ /^<[a-z]/) {
+        print "<h2 id=\"" strip_markdown(prev) "\">" prev "</h2>"
+        has_prev = 0
+    } else {
+        if (has_prev) {
+            line = prev
+            if (line ~ /^# /) {
+                sub(/^# /, "", line); print "<h1 id=\"" strip_markdown(line) "\">" line "</h1>"
+            } else if (line ~ /^## /) {
+                sub(/^## /, "", line); print "<h2 id=\"" strip_markdown(line) "\">" line "</h2>"
+            } else if (line ~ /^### /) {
+                sub(/^### /, "", line); print "<h3 id=\"" strip_markdown(line) "\">" line "</h3>"
+            } else if (line ~ /^#### /) {
+                sub(/^#### /, "", line); print "<h4 id=\"" strip_markdown(line) "\">" line "</h4>"
+            } else if (line ~ /^##### /) {
+                sub(/^##### /, "", line); print "<h5 id=\"" strip_markdown(line) "\">" line "</h5>"
+            } else if (line ~ /^###### /) {
+                sub(/^###### /, "", line); print "<h6 id=\"" strip_markdown(line) "\">" line "</h6>"
+            } else {
+                print prev
+            }
+        }
+        prev = $0
+        has_prev = 1
+    }
+}
+END {
+    if (has_prev) {
+        line = prev
+        if (line ~ /^# /) {
+            sub(/^# /, "", line); print "<h1 id=\"" strip_markdown(line) "\">" line "</h1>"
+        } else {
+            print prev
+        }
+    }
+}

awk/indented_code.awk

@@ -0,0 +1,9 @@
+BEGIN { in_code = 0 }
+/^	|    / {
+    if (!in_code) { print "<pre><code>"; in_code = 1 }
+    sub(/^	|    /, "", $0)
+    gsub(/&/, "&amp;"); gsub(/</, "&lt;"); gsub(/>/, "&gt;")
+    print; next
+}
+{ if (in_code) { print "</code></pre>"; in_code = 0 } print }
+END { if (in_code) print "</code></pre>" }

awk/lists.awk

@@ -0,0 +1,66 @@
+BEGIN {
+    depth = 0
+    in_pre = 0
+}
+
+{
+    if ($0 ~ /^<pre>/) in_pre = 1
+    if (in_pre) {
+        while (depth > 0) { print "</" cur_type[depth] ">"; depth-- }
+        print
+        if ($0 ~ /<\/pre>/) in_pre = 0
+        next
+    }
+
+    line = $0
+    type = ""
+    # match list marker and its preceding spaces
+    if (line ~ /^[ \t]*[*+-] /) {
+        type = "ul"
+        match(line, /^[ \t]*[*+-] /)
+        marker_len = RLENGTH
+    } else if (line ~ /^[ \t]*[0-9]+\. /) {
+        type = "ol"
+        match(line, /^[ \t]*[0-9]+\. /)
+        marker_len = RLENGTH
+    }
+
+    if (type != "") {
+        content = substr(line, marker_len + 1)
+        # get indentation level
+        match(line, /^[ \t]*/)
+        indent = RLENGTH
+        
+        if (depth == 0 || indent > cur_indent[depth]) {
+            depth++
+            cur_indent[depth] = indent
+            cur_type[depth] = type
+            print "<" type ">"
+        } else {
+            while (depth > 1 && indent < cur_indent[depth]) {
+                print "</" cur_type[depth] ">"
+                depth--
+            }
+            if (type != cur_type[depth]) {
+                print "</" cur_type[depth] ">"
+                cur_type[depth] = type
+                print "<" type ">"
+            }
+        }
+
+        print "<li>" content "</li>"
+    } else {
+        while (depth > 0) {
+            print "</" cur_type[depth] ">"
+            depth--
+        }
+        print line
+    }
+}
+
+END {
+    while (depth > 0) {
+        print "</" cur_type[depth] ">"
+        depth--
+    }
+}

awk/markdown_embed.awk

@@ -119,11 +119,35 @@ function css_highlight_line(line,    m, prop, val) {
         return "<span class=\"tok-punc\">}</span>"
     }
 
-    if (match(line, /^([[:space:]]*)(--?[A-Za-z0-9_-]+)([[:space:]]*:[[:space:]]*)([^;]*)(;?[[:space:]]*)$/, m)) {
-        prop = "<span class=\"tok-prop\">" m[2] "</span>"
-        gsub(/var\(--[A-Za-z0-9_-]+\)/, "<span class=\"tok-var\">&</span>", m[4])
-        val = "<span class=\"tok-val\">" m[4] "</span>"
-        return m[1] prop m[3] val m[5]
+    if (line ~ /^[[:space:]]*--?[A-Za-z0-9_-]+[[:space:]]*:[[:space:]]*[^;]*;?[[:space:]]*$/) {
+        match(line, /:[[:space:]]*/)
+        sep_pos = RSTART
+        sep_len = RLENGTH
+        
+        pre_sep = substr(line, 1, sep_pos - 1)
+        sep = substr(line, sep_pos, sep_len)
+        post_sep = substr(line, sep_pos + sep_len)
+        
+        match(pre_sep, /--?[A-Za-z0-9_-]+/)
+        prop_pos = RSTART
+        prop_len = RLENGTH
+        
+        indent = substr(pre_sep, 1, prop_pos - 1)
+        prop_name = substr(pre_sep, prop_pos, prop_len)
+        
+        if (match(post_sep, /;[[:space:]]*$/)) {
+            val_part = substr(post_sep, 1, RSTART - 1)
+            suffix = substr(post_sep, RSTART)
+        } else {
+            val_part = post_sep
+            suffix = ""
+        }
+        
+        prop = "<span class=\"tok-prop\">" prop_name "</span>"
+        gsub(/var\(--[A-Za-z0-9_-]+\)/, "<span class=\"tok-var\">&</span>", val_part)
+        val = "<span class=\"tok-val\">" val_part "</span>"
+        
+        return indent prop sep val suffix
     }
 
     return line

awk/markdown_inline.awk

@@ -0,0 +1,173 @@
+BEGIN {
+    in_pre = 0
+}
+
+{
+    if ($0 ~ /<pre>/) {
+        in_pre = 1
+    }
+    
+    if (in_pre) {
+        print
+        if ($0 ~ /<\/pre>/) {
+            in_pre = 0
+        }
+        next
+    }
+
+    line = $0
+
+    # automatic links
+    while (match(line, /<https?:\/\/[^>]+>/)) {
+        start = RSTART; len = RLENGTH
+        url = substr(line, start + 1, len - 2)
+        repl = "<a href=\"" url "\">" url "</a>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+
+    # automatic email address links
+    while (match(line, /<[A-Za-z0-9._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,}>/)) {
+        start = RSTART; len = RLENGTH
+        email = substr(line, start + 1, len - 2)
+        repl = "<a href=\"mailto:" email "\">" email "</a>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+
+    # force-inline image syntax (double bang)
+    while (match(line, /!!\[[^\]]*\]\([^\)]+ "[^"]*"\)/)) {
+        start = RSTART; len = RLENGTH
+        token = substr(line, start, len)
+        match(token, /\[[^\]]*\]/); alt = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /"[^"]*"/); title = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /\([^\)]+/); inner = substr(token, RSTART + 1, RLENGTH - 1)
+        sub(/[[:space:]]*"[^"]*"/, "", inner); src = inner
+        repl = "<img data-force-inline=\"1\" alt=\"" alt "\" src=\"" src "\" title=\"" title "\" />"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    while (match(line, /!!\[[^\]]*\]\([^\)]+\)/)) {
+        start = RSTART; len = RLENGTH
+        token = substr(line, start, len)
+        match(token, /\[[^\]]*\]/); alt = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /\([^\)]+/); src = substr(token, RSTART + 1, RLENGTH - 1)
+        repl = "<img data-force-inline=\"1\" alt=\"" alt "\" src=\"" src "\" />"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+
+    # inline image
+    while (match(line, /!\[[^\]]*\]\([^\)]+ "[^"]*"\)/)) {
+        start = RSTART; len = RLENGTH
+        if (start > 1 && substr(line, start - 1, 1) == "\\") break
+        token = substr(line, start, len)
+        match(token, /\[[^\]]*\]/); alt = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /"[^"]*"/); title = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /\([^\)]+/); inner = substr(token, RSTART + 1, RLENGTH - 1)
+        sub(/[[:space:]]*"[^"]*"/, "", inner); src = inner
+        repl = "<img alt=\"" alt "\" src=\"" src "\" title=\"" title "\" />"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    while (match(line, /!\[[^\]]*\]\([^\)]+\)/)) {
+        start = RSTART; len = RLENGTH
+        if (start > 1 && substr(line, start - 1, 1) == "\\") break
+        token = substr(line, start, len)
+        match(token, /\[[^\]]*\]/); alt = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /\([^\)]+/); src = substr(token, RSTART + 1, RLENGTH - 1)
+        repl = "<img alt=\"" alt "\" src=\"" src "\" />"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+
+    # inline link
+    while (match(line, /\[[^\]]*\]\([^\)]+ "[^"]*"\)/)) {
+        start = RSTART; len = RLENGTH
+        if (start > 1 && (substr(line, start - 1, 1) == "\\" || substr(line, start - 1, 1) == "!")) break
+        token = substr(line, start, len)
+        match(token, /\[[^\]]*\]/); text = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /"[^"]*"/); title = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /\([^\)]+/); inner = substr(token, RSTART + 1, RLENGTH - 1)
+        sub(/[[:space:]]*"[^"]*"/, "", inner); href = inner
+        repl = "<a href=\"" href "\" title=\"" title "\">" text "</a>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    while (match(line, /\[[^\]]*\]\([^\)]+\)/)) {
+        start = RSTART; len = RLENGTH
+        if (start > 1 && (substr(line, start - 1, 1) == "\\" || substr(line, start - 1, 1) == "!")) break
+        token = substr(line, start, len)
+        match(token, /\[[^\]]*\]/); text = substr(token, RSTART + 1, RLENGTH - 2)
+        match(token, /\([^\)]+/); href = substr(token, RSTART + 1, RLENGTH - 1)
+        repl = "<a href=\"" href "\">" text "</a>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+
+    # MFM font syntax
+    while (match(line, /\$\[font\.serif [^\]]+\]/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 13, len - 14)
+        line = substr(line, 1, start - 1) "<span style=\"font-family: serif;\">" content "</span>" substr(line, start + len)
+    }
+    while (match(line, /\$\[font\.monospace [^\]]+\]/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 17, len - 18)
+        line = substr(line, 1, start - 1) "<span style=\"font-family: monospace;\">" content "</span>" substr(line, start + len)
+    }
+    while (match(line, /\$\[font\.sans [^\]]+\]/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 12, len - 13)
+        line = substr(line, 1, start - 1) "<span style=\"font-family: sans-serif;\">" content "</span>" substr(line, start + len)
+    }
+
+    # Bold, Italic, Strikethrough (BRE-like logic in AWK)
+    # Strong Bold **
+    while (match(line, /\*\*[^*]+\*\*/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 2, len - 4)
+        repl = "<strong>" content "</strong>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    # Strong Bold __
+    while (match(line, /__[^_]+__/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 2, len - 4)
+        repl = "<strong>" content "</strong>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    # Italic *
+    while (match(line, /\*[^*]+\*/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 1, len - 2)
+        repl = "<em>" content "</em>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    # Italic _
+    while (match(line, /_[^_]+_/)) {
+        start = RSTART; len = RLENGTH
+        if (start > 1 && substr(line, start - 1, 1) == "\\") break
+        content = substr(line, start + 1, len - 2)
+        repl = "<em>" content "</em>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+    # Strikethrough ~~
+    while (match(line, /~~[^~]+~~/)) {
+        start = RSTART; len = RLENGTH
+        content = substr(line, start + 2, len - 4)
+        repl = "<strike>" content "</strike>"
+        line = substr(line, 1, start - 1) repl substr(line, start + len)
+    }
+
+    # special characters
+    if (line !~ /&[A-Za-z0-9#]+;/) {
+        gsub(/&/, "&amp;", line)
+    }
+    
+    p = 1
+    while (match(substr(line, p), /</)) {
+        start = p + RSTART - 1
+        next_char = substr(line, start + 1, 1)
+        if (next_char !~ /^[\/A-Za-z]/) {
+            line = substr(line, 1, start - 1) "&lt;" substr(line, start + 1)
+            p = start + 4
+        } else {
+            p = start + 1
+        }
+    }
+
+    print line
+}

awk/mask_inline_code.awk

@@ -0,0 +1,85 @@
+function mask(s,    t) {
+    t = s
+    gsub(/\*/, "\034P0\034", t)
+    gsub(/_/, "\034P1\034", t)
+    gsub(/`/, "\034P2\034", t)
+    gsub(/\[/, "\034P3\034", t)
+    gsub(/\]/, "\034P4\034", t)
+    gsub(/\(/, "\034P5\034", t)
+    gsub(/\)/, "\034P6\034", t)
+    gsub(/!/, "\034P7\034", t)
+    gsub(/\$/, "\034P8\034", t)
+    gsub(/#/, "\034P9\034", t)
+    gsub(/\+/, "\034P10\034", t)
+    gsub(/-/, "\034P11\034", t)
+    gsub(/\\/, "\034P12\034", t)
+    gsub(/</, "\034P13\034", t)
+    gsub(/>/, "\034P14\034", t)
+    return t
+}
+{
+    # backslash escapes
+    gsub(/\\\*/, "\034P0\034")
+    gsub(/\\_/, "\034P1\034")
+    gsub(/\\`/, "\034P2\034")
+    gsub(/\\\[/, "\034P3\034")
+    gsub(/\\\]/, "\034P4\034")
+    gsub(/\\\(/, "\034P5\034")
+    gsub(/\\\)/, "\034P6\034")
+    gsub(/\\!/, "\034P7\034")
+    gsub(/\\\$/, "\034P8\034")
+    gsub(/\\#/, "\034P9\034")
+    gsub(/\\\+/, "\034P10\034")
+    gsub(/\\\-/, "\034P11\034")
+    gsub(/\\\\/, "\034P12\034")
+    gsub(/\\</, "\034P13\034")
+    gsub(/\\>/, "\034P14\034")
+
+    # inline code (1 or 2 backticks)
+    line = $0
+    if (line ~ /^```/) {
+        print line
+        next
+    }
+    out = ""
+    p = 1
+    while (match(substr(line, p), /`+/)) {
+        pstart = p + RSTART - 1
+        plen = RLENGTH
+        if (plen >= 3) {
+            out = out substr(line, p, pstart - p + plen)
+            p = pstart + plen
+            continue
+        }
+
+        # Found 1 or 2 backticks at pstart
+        # Search for closing marker
+        marker = substr(line, pstart, plen)
+        tail = substr(line, pstart + plen)
+        mpos = index(tail, marker)
+        if (mpos > 0) {
+            # Check if it is followed by more backticks
+            if (substr(tail, mpos + plen, 1) == "`") {
+                # Not a match, treat as literal
+                out = out substr(line, p, pstart - p + plen)
+                p = pstart + plen
+                continue
+            }
+            
+            # Found match!
+            content = substr(tail, 1, mpos - 1)
+            out = out substr(line, p, pstart - p)
+            if (plen == 2 && substr(content, 1, 1) == " " && substr(content, length(content), 1) == " ") {
+                content = substr(content, 2, length(content) - 2)
+            }
+            out = out "<code>" mask(content) "</code>"
+            p = pstart + plen + mpos + plen - 1
+        } else {
+            # No closing marker, treat as literal
+            out = out substr(line, p, pstart - p + plen)
+            p = pstart + plen
+        }
+    }
+    out = out substr(line, p)
+    print out
+}

awk/mask_plain.awk

@@ -0,0 +1,52 @@
+function find_unescaped_tag(s, tag,    p, off, pos) {
+    p = 1
+    while (1) {
+        off = index(substr(s, p), tag)
+        if (off == 0) return 0
+        pos = p + off - 1
+        if (pos == 1 || substr(s, pos - 1, 1) != "\\") return pos
+        p = pos + 1
+    }
+}
+
+function mask_plain(s,    t) {
+    t = s
+    gsub(/\*/, "\034P0\034", t)
+    gsub(/_/, "\034P1\034", t)
+    gsub(/`/, "\034P2\034", t)
+    gsub(/\[/, "\034P3\034", t)
+    gsub(/\]/, "\034P4\034", t)
+    gsub(/\(/, "\034P5\034", t)
+    gsub(/\)/, "\034P6\034", t)
+    gsub(/!/, "\034P7\034", t)
+    gsub(/\$/, "\034P8\034", t)
+    return t
+}
+BEGIN { in_plain = 0 }
+{
+    line = $0
+    out = ""
+    while (1) {
+        if (!in_plain) {
+            pos = find_unescaped_tag(line, "<plain>")
+            if (pos == 0) {
+                out = out line
+                break
+            }
+            out = out substr(line, 1, pos - 1) "<mfmplain>"
+            line = substr(line, pos + 7)
+            in_plain = 1
+        } else {
+            pos = find_unescaped_tag(line, "</plain>")
+            if (pos == 0) {
+                out = out mask_plain(line)
+                line = ""
+                break
+            }
+            out = out mask_plain(substr(line, 1, pos - 1)) "</mfmplain>"
+            line = substr(line, pos + 8)
+            in_plain = 0
+        }
+    }
+    print out
+}

awk/paragraphs.awk

@@ -0,0 +1,43 @@
+BEGIN {
+    in_p = 0
+    in_pre = 0
+}
+
+{
+    if ($0 ~ /^<pre>/) in_pre = 1
+    
+    if (in_pre) {
+        if (in_p) { print "</p>"; in_p = 0 }
+        print
+        if ($0 ~ /<\/pre>/) in_pre = 0
+        next
+    }
+
+    if ($0 ~ /^<\/?(div|table|p|[ou]l|h[1-6]|[bh]r|blockquote|li)/) {
+        if (in_p) {
+            print "</p>"
+            in_p = 0
+        }
+        print
+        next
+    }
+
+    if ($0 == "") {
+        if (in_p) {
+            print "</p>"
+            in_p = 0
+        }
+        print
+        next
+    }
+
+    if (!in_p) {
+        print "<p>"
+        in_p = 1
+    }
+    print
+}
+
+END {
+    if (in_p) print "</p>"
+}

awk/pipe_tables.awk

@@ -0,0 +1,143 @@
+function trim(s) {
+    sub(/^[[:space:]]+/, "", s)
+    sub(/[[:space:]]+$/, "", s)
+    return s
+}
+
+function is_table_row(line, t) {
+    t = line
+    return (t ~ /^[[:space:]]*\|/ && t ~ /\|[[:space:]]*$/)
+}
+
+function is_table_sep(line, t) {
+    if (!is_table_row(line)) return 0
+    t = line
+    gsub(/[|:\-[:space:]]/, "", t)
+    return (t == "" && line ~ /-/)
+}
+
+function split_row(line, out, n, i, raw) {
+    raw = line
+    sub(/^[[:space:]]*\|/, "", raw)
+    sub(/\|[[:space:]]*$/, "", raw)
+    n = split(raw, out, /\|/)
+    for (i = 1; i <= n; i++) out[i] = trim(out[i])
+    return n
+}
+
+function align_for(sep, t) {
+    t = trim(sep)
+    if (t ~ /^:-+:$/) return "center"
+    if (t ~ /^:-+$/) return "left"
+    if (t ~ /^-+:$/) return "right"
+    return ""
+}
+
+function render_cell(cell, inner) {
+    inner = trim(cell)
+    if (inner ~ /^```.*```$/) {
+        sub(/^```[[:space:]]*/, "", inner)
+        sub(/[[:space:]]*```$/, "", inner)
+        return "<pre><code>" inner "</code></pre>"
+    }
+    return inner
+}
+
+BEGIN { count = 0 }
+{ lines[++count] = $0 }
+
+END {
+    in_pre = 0
+    i = 1
+    while (i <= count) {
+        if (lines[i] ~ /^<pre><code>/) {
+            in_pre = 1
+            print lines[i]
+            i++
+            continue
+        }
+        if (in_pre) {
+            print lines[i]
+            if (lines[i] ~ /^<\/code><\/pre>/) in_pre = 0
+            i++
+            continue
+        }
+
+        if (i < count && is_table_row(lines[i]) && is_table_sep(lines[i + 1])) {
+            n_header = split_row(lines[i], header)
+            n_sep = split_row(lines[i + 1], sep)
+            n_cols = (n_header > n_sep ? n_header : n_sep)
+
+            print "<table>"
+            print "<thead>"
+            print "<tr>"
+            for (c = 1; c <= n_cols; c++) {
+                cell = (c <= n_header ? render_cell(header[c]) : "")
+                a = (c <= n_sep ? align_for(sep[c]) : "")
+                if (a != "") print "<th style=\"text-align: " a ";\">" cell "</th>"
+                else print "<th>" cell "</th>"
+            }
+            print "</tr>"
+            print "</thead>"
+
+            j = i + 2
+            print "<tbody>"
+            while (j <= count && is_table_row(lines[j])) {
+                n_body = split_row(lines[j], body)
+                print "<tr>"
+                for (c = 1; c <= n_cols; c++) {
+                    cell = (c <= n_body ? render_cell(body[c]) : "")
+                    a = (c <= n_sep ? align_for(sep[c]) : "")
+                    if (a != "") print "<td style=\"text-align: " a ";\">" cell "</td>"
+                    else print "<td>" cell "</td>"
+                }
+                print "</tr>"
+                j++
+            }
+            print "</tbody>"
+            print "</table>"
+
+            i = j
+            continue
+        }
+
+        if (is_table_sep(lines[i]) && i < count && is_table_row(lines[i + 1])) {
+            n_sep = split_row(lines[i], sep)
+            n_cols = n_sep
+
+            print "<table>"
+            print "<thead>"
+            print "<tr>"
+            for (c = 1; c <= n_cols; c++) {
+                a = align_for(sep[c])
+                if (a != "") print "<th style=\"text-align: " a ";\"></th>"
+                else print "<th></th>"
+            }
+            print "</tr>"
+            print "</thead>"
+
+            j = i + 1
+            print "<tbody>"
+            while (j <= count && is_table_row(lines[j])) {
+                n_body = split_row(lines[j], body)
+                print "<tr>"
+                for (c = 1; c <= n_cols; c++) {
+                    cell = (c <= n_body ? render_cell(body[c]) : "")
+                    a = (c <= n_sep ? align_for(sep[c]) : "")
+                    if (a != "") print "<td style=\"text-align: " a ";\">" cell "</td>"
+                    else print "<td>" cell "</td>"
+                }
+                print "</tr>"
+                j++
+            }
+            print "</tbody>"
+            print "</table>"
+
+            i = j
+            continue
+        }
+
+        print lines[i]
+        i++
+    }
+}

awk/update_site_conf.awk

@@ -0,0 +1,10 @@
+BEGIN { done = 0 }
+/^title[[:space:]]*=/ {
+    print "title = \"" new_title "\""
+    done = 1
+    next
+}
+{ print }
+END {
+    if (!done) print "title = \"" new_title "\""
+}